I managed to get sparrow into landscape mode using home button at right and
[self createPhysicsWorld];
st = [[SPSprite alloc] init];
st.rotation = SP_D2R(90);
st.x = 320;
[self addChild:st];
But now I need to get box2d in a landscape mode where X becomes 480 and Y is 320
Any ideas?
baike
Moderator
I just use macros for box2d.
#define PPM 8.0f // Pixels per meter
#define M2PX(x) ((x) * PPM) // Meters to pixels X-Axis
#define M2PY(y) (320.0f - ((y) * PPM)) // Meters to pixels Y-Axis
#define P2MX(x) ((x) / PPM) // Pixels to meters X-Axis
#define P2MY(y) ((320.0f - (y)) / PPM) // Pixels to meters Y-AxisAll it really does is convert your pixels to meters (and back) and inverts the Y-Axis. Then I just add a readonly property to my sprites that represent box2d objects called px and py. These return M2PX(body->GetPosition().x) and M2PY(body->GetPosition().y) respectively. You can use this each frame to make sure your sprites are mimicking their box2d counterparts. Rotation should be -body->GetAngle().
baike
Moderator
Btw, if you place a base sprite on the stage and then add all your other content to that base sprite, you can rotate the base sprite and then treat the iphone's vertical dimension as the x-axis. The box2d world doesn't really have an orientation beyond the way you choose to interpret its output. You can change the macros to fit your desired representation of what's going on in the underlying invisible box2d world.
As you can see I have already done that.
[self createPhysicsWorld];
st = [[SPSprite alloc] init];
st.rotation = SP_D2R(90);
st.x = 320;
[self addChild:st];
My question is how do I add a physical body for a view in landscape mode?
-(void)addPhysicalBodyForView:(SPDisplayObject*)physicalView
and
Put a "wall" at the bottom (when the home button is to the right with;
b2EdgeShape groundBox;
groundBox.Set(b2Vec2(0,0), b2Vec2(480.0f/PTM_RATIO,0));
groundBody->CreateFixture(&groundBox, 0);
baike
Moderator
The only thing landscape mode will do is give you more room to move on the x-axis before your character goes off screen (and less on the y-axis). I suggest you make a new test in the box2d testbed and prototype your idea there before making it in Sparrow. There's a bunch of examples in the testbed to get started.
I still don't think you comprehend my problem. I understand what it does and what it doesn't do with landscape.
My problem is positioning vectors in landscape using Box2D with Sparrow.
Again posting code;
b2EdgeShape groundBox;
groundBox.Set(b2Vec2(0,0), b2Vec2(480.0f/PTM_RATIO,0));
groundBody->CreateFixture(&groundBox, 0);
Should make a vector at my bottom side of the iphone in landscape mode.
But it doesn't.
groundBox.Set(b2Vec2(0,0), b2Vec2(480.0f/PTM_RATIO,0));
Try changing this line to,
groundBox.Set(b2Vec2(0,0), b2Vec2(160.0f/PTM_RATIO,0));
Anyway here is the code. This is turning up to be a major f*cking pain.
https://gist.github.com/736909
I got interface landscape home button right in the info.plist.
baike
Moderator
The problem is you're coding blind and guessing at where you went wrong. In my quick look at your git repo it seems to be fine, but it'd be a lot easier if you run it through the testbed and *see* the outputs. Then you can go Aha! I just need to move this over here or whatever.
Hehe, yeah I do give that impression, the thing is the testbed is way too complicated to me to use. Also I did get it to work in PORTRAIT which the testbed already has. That ain't no concern to me. What is a concern is the landscape.
Could you run my gist and upload the xcode project zip somewhere? If it.. "just works".
baike
Moderator
If you're still having troubles when I get home, I will make a quick project that does it.
If your world may get more complex, you're going to need to visualize it. For the testbed, follow these steps:
1. Go to TestEntries.cpp.
2. Add your own test entry (in g_testEntries[] and the appropriate include file).
3. Copy one of the other tests, change its name and rip the guts out of it.
4. Build your own world in this new test file and then run the testbed.
Now you can see your world running. You can zoom in and out and see that maybe you accidentally built your world half a mile off screen - something that would just completely throw you if it happened on a tiny iOS screen. You can take your world exactly as it is in that test file and it will work in Sparrow. Note that I am using Box2D v2.1.2.
Alright I copied the pyramid.h and I set it up in TestEntries.mm
I added [application setStatusBarOrientation: UIInterfaceOrientationLandscapeRight animated:NO];
in the app delegate.
Yet no good.
(0,0) is lower left corner
Can you make me a landscape example where boxes are dropping from "up" to "down".
Put a vector in from 0.320 to 480.320
thats all I ask for and need.
Seriously, it's pissing me off that it isn't that clear.
The screen is 480px high if you put something at 480 it'll be off the end of the screen and invisible to you.
Also if you have done landscape right then your stage should now be 320px high and 480px wide so 480 will be WAY off, by telling you to put it at 160 at least some part of it should be guaranteed to be visible, if not then there's another error to.
Here is a screenshot showing what the hell I ma talking about about
http://dl.getdropbox.com/u/1367825/Screen%20shot%202010-12-11%20at%205.53.16%20PM.png
As you can see that should not be so.
Also what the hell are you talking about= if you put a vector that stops the blocks from falling from 0 to 480 on the x axel it won't be way off. Are you confused?
baike
Moderator
Start a new Sparrow project, do the Box2D setup dance and then paste this over your Game.mm implementation:
#import "Game.h"
#import <Box2D/Box2D.h>
#define PPM 8.0f // Pixels per meter
#define M2P(a) ((a) * PPM) // Meter to pixels ratio
#define P2M(a) ((a) / PPM) // Pixels to meters ratio
#define M2PX(x) ((x) * PPM) // Meters to Pixels X-Axis
#define M2PY(y) (320.0f - ((y) * PPM)) // Meters to Pixels Y-Axis
#define P2MX(x) ((x) / PPM) // Pixels to Meters
#define P2MY(y) ((320.0f - (y)) / PPM) // Pixels to Meters
b2World *world;
SPSprite *stageProxy;
@interface Game ()
- (void)addToOrientedStage:(SPDisplayObject *)obj;
- (void)createPhysicsWorld;
- (void)addPhysicalBodyForView:(SPDisplayObject *)view width:(float)width height:(float)height;
@end
@implementation Game
- (id)initWithWidth:(float)width height:(float)height {
if (self = [super initWithWidth:width height:height]) {
// Setup orientation sprite
stageProxy = [[SPSprite alloc] init];
stageProxy.rotation = SP_D2R(90);
stageProxy.x = self.width;
[self addChild:stageProxy];
// Create world
[self createPhysicsWorld];
// Populate world
for (int i = 0; i < 20; ++i) {
uint rand = arc4random();
SPSprite *sprite = [[SPSprite alloc] init];
sprite.x = 10.0f + rand % 460;
sprite.y = 10.0f + rand % 50;
sprite.rotation = rand % 6;
SPQuad *quad = [[SPQuad alloc] initWithWidth:10.0f height:10.0f];
quad.x = -quad.width / 2;
quad.y = -quad.height / 2;
quad.color = 0xff0000;
[sprite addChild:quad];
[self addToOrientedStage:sprite];
[self addPhysicalBodyForView:sprite width:quad.width height:quad.height];
[quad release];
[sprite release];
}
}
return self;
}
- (void)addToOrientedStage:(SPDisplayObject *)view {
[stageProxy addChild:view];
}
- (void)createPhysicsWorld {
float groundWidth = 480.0f;
float groundHeight = 16.0f;
bool doSleep = true;
b2Vec2 gravity;
gravity.Set(0.0f, -9.81f);
world = new b2World(gravity, doSleep);
world->SetContinuousPhysics(true);
b2BodyDef bd;
bd.position.Set(P2MX(groundWidth / 2), P2MY(320.0f - groundHeight / 2));
SPSprite *sprite = [SPSprite sprite];
sprite.x = M2PX(bd.position.x);
sprite.y = M2PY(bd.position.y);
SPQuad *quad = [[SPQuad alloc] initWithWidth:groundWidth height:groundHeight];
quad.x = -quad.width / 2;
quad.y = -quad.height / 2;
quad.color = 0x00ff00;
[sprite addChild:quad];
[self addToOrientedStage:sprite];
bd.userData = sprite;
b2Body *ground = world->CreateBody(&bd);
b2PolygonShape shape;
shape.SetAsBox(P2M(groundWidth / 2), P2M(groundHeight / 2), b2Vec2(0.0f, 0.0f), 0.0f);
b2FixtureDef fd;
fd.shape = &shape;
fd.density = 0.0f;
fd.restitution = 0.25f;
ground->CreateFixture(&fd);
}
- (void)addPhysicalBodyForView:(SPDisplayObject *)view width:(float)width height:(float)height {
b2BodyDef bd;
bd.type = b2_dynamicBody;
bd.position.Set(P2MX(view.x), P2MY(view.y));
bd.angle = -view.rotation;
bd.userData = view;
b2Body *body = world->CreateBody(&bd);
b2PolygonShape dynamicBox;
dynamicBox.SetAsBox(P2M(width / 2), P2M(height / 2), b2Vec2(0.0f, 0.0f), 0.0f);
b2FixtureDef fd;
fd.shape = &dynamicBox;
fd.density = 2.0f;
fd.friction = 0.3f;
fd.restitution = 0.25f;
body->CreateFixture(&fd);
}
- (void)advanceTime:(double)seconds {
world->Step(1.0f / 30.0f, 6, 2);
for (b2Body *b = world->GetBodyList(); b; b = b->GetNext()) {
if (b->GetUserData() != NULL) {
SPDisplayObject *obj = (SPDisplayObject *)b->GetUserData();
b2Vec2 pos = b->GetPosition();
CGPoint center = CGPointMake(M2PX(pos.x), M2PY(pos.y));
obj.x = center.x;
obj.y = center.y;
obj.rotation = -b->GetAngle();
}
}
}
@endAnd mate, I know you're frustrated, but these forums have a very civil vibe and it'd be good if you can help to maintain that.
Yeah it was pretty frustrating, I hope I didn't snap at anyone, even though it was no excuse.
Thanks a lot man!
In the tick, (320.0f - ((y) * PPM))
was my problem.
I use
CGPoint newCenter = CGPointMake(b->GetPosition().x * PTM_RATIO,
self.st.stage.width - b->GetPosition().y * PTM_RATIO);
I had
CGPoint newCenter = CGPointMake(b->GetPosition().x * PTM_RATIO,
self.height - b->GetPosition().y * PTM_RATIO);
baike
Moderator
If you do want to prototype box2d stuff on iOS, one thing I find helps to debug is scaling the stageProxy down to 0.25f and you can see a lot more area and find where objects have been misplaced or may be heading off into the black abyss. Add a touch listener that toggles the scale and it can really help.
baike thanks for the supprot man, Do you got any code examples or demo code on some games using sparrow and box2d? Like parrallex, or jumping and etc.
Anyway, I decided to go with this instead;
b2BodyDef groundBodyDef;
groundBodyDef.position.Set(0, 0); // bottom-left corner
b2Body* groundBody = world->CreateBody(&groundBodyDef);
b2EdgeShape groundBox;
//THis is easyer to think about since we are using two points in the "space"
groundBox.Set(b2Vec2(0,0),b2Vec2(480 / PTM_RATIO,0));
groundBody->CreateFixture(&groundBox, 0);
baike
Moderator
No, I haven't tried any platformers. For jumping I would use ApplyLinearImpulse with a vertical vector applied at the player's center. Then gravity should bring the player back down and the player's horizontal velocity will give the jump an arc if he's already moving. I'd also make the character's body fixed-rotation (some box2d setting). You kind of have to play around with the physics until you're happy with them.
For platformer scrolling you will likely need to load your entire box2d level at once (that is the bodies, shapes and fixtures that define it). These kind of settings are relatively small compared to graphics. Then you'd likely have a pool of sprites that encompasses all the visible elements in your game that can be attached to a b2Body.
With 1 dimension, you can only ever have 2 screens of images viewable at once (even though only half of each screen). With 2 it's 4 screens, so you'd base your Sprite pools on the maximum number of objects of that kind that can be visible at once.
Then you would need a SceneManager to decide when it's safe to re-assign sprites from the out-of-scene b2Bodies to the ones that are now visible. Otherwise you will have way too many sprites at once or you will have to be constantly hitting malloc for each new screen.
Parallax scrolling would be easy enough. Your background moves in the opposite direction to your character. Each of the layers would just have a fractional multiplier that sets its scrolling speed relative to the character's speed. You can probably use scaled up low res images for the far-most layer as it should not steal attention from the front layers.
Anyway, there's a deal of work in all that, but I'm sure you're up to it.
Yeah actually I just did. However how do you get an "arc" if the characters horizontal velocity is 0.
I mean everything else moves except the player. And he can jump by increasing it's Y velocity.
Or... does he need an arc if it's parallax?
I mean maybe the parallax will simulate an arc?
Look at games like cannabalt or such
Thanks for ALL your help dude, REALLY appreciate it. I am getting into Box2d and Sparrow as we speak.
You must log in to post.